Unified Query Plan Representation

plan     ::= tree? properties

tree     ::= node ( '--children-->' '{' tree ( ',' tree )* '}' )?

node     ::= operation properties

operation
         ::= 'Operation' ':' operation_category '->' operation_identifier

properties
         ::= ( property ( ',' property )* )?

property ::= property_category '->' property_identifier ':' value

operation_category
         ::= 'Producer'
           | 'Combinator'
           | 'Join'
           | 'Folder'
           | 'Executor'
           | 'Projector'
           | 'Consumer'

property_category
         ::= 'Cardinality'
           | 'Cost'
           | 'Configuration'
           | 'Status'

operation_identifier
         ::= keyword

property_identifier
         ::= keyword

keyword  ::= letter ( letter | digit | '_' )*

value    ::= string
           | number
           | boolean
           | 'null'

string   ::= '"' ( letter | digit )* '"'

number   ::= '-'? digit+

boolean  ::= 'true'
           | 'false'

letter   ::= [a-zA-Z]